Learning Forum

[manuel.uruena]

Dear all,

I am modelling a steel tube for axial compression test. I would like to introduce residual stresses that the unloaded tubes have.

One way to do it is with the INISTATE command, in which you apply inistal stress or strain to elements in their integration points. My problem with this command is that when I solve just with the inital stresses, these redistribute and concentrate at the boundary conditions. Thus, this is not an accurate state of real residual stressed tubes. How can I avoid this?

Another way is using an ISFILE. But I dont know how to operate with this command, because ISFILE,READ reads an initial stress state from a file into ANSYS. This command can be used in recent APDL versions, but no longer appears in the command help. How do I generate this file?

Which option should I use?

Thanks

[Bill Bulat]

Maybe instead of applying BCs directly to the tube mesh nodes, you could model two blocks, one above and one below the tube, and used standard contact between the block and tube surfaces. Use "adjust to touch" in the contact to get the simulation going. Impose the axial compression on the blocks instead of on the tube.

I think INISTATE should work fine, but if you would like to try ISFILE, here are parts of a small test using 2 layer SHELL181 that illustrates usage:
fini
/cle

/vie,1,1,1,1
/vup,1,z
/esha,1


C*********************************************************
C*** PARAMETERS
C*********************************************************
l=1000 ! BEAM LENGTH (um)
w=100 ! BEAM WIDTH
t_bot=2 ! BOTTOM LAYER (LAYER #1) THICKNESS
t_top=5 ! TOP LAYER (LAYER #2) THICKNESS
sx_bot=20 ! INITIAL STRESSES FOR BOTTOM LAYER #1
sy_bot=0
sz_bot=0
sxy_bot=0
syz_bot=0
sxz_bot=0

sx_top=-20 ! INITIAL STRESSES FOR TOP LAYER #2
sy_bot=0
sz_bot=0
sxy_bot=0
syz_bot=0
sxz_bot=0

/title,SX_top = %sx_top%, SX_bot = %sx_bot%


C*********************************************************
C*** MODEL
C*********************************************************
/prep7

et,1,181

mp,ex,1,1.6e5
mp,nuxy,1,0.22

mp,ex,2,1.6e5
mp,nuxy,2,0.22

sectype,1,shell
secdata,t_bot,1,0,,bot
secdata,t_top,2,0,,top

rect,0,l,-w/2,w/2
ames,all

nsel,s,loc,x
d,all,all
alls


fini


C*********************************************************
C*** WRITE INITIAL STRESS FILE
C*********************************************************
/solu
alls

*get,nelems,elem,,count
elm=0

*cfo,file,ist

*do,i,1,nelems
elm=elnext(elm)

*vwrite
('!SXSYSZSXYSYZSXZ')
*vwrite,elm,1
('eis,',F9.0,tl1,',',F2.0,tl1,' ')
*vwrite,sx_bot,sy_bot,sz_bot,sxy_bot,syz_bot,sxz_bot
(F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3)
*vwrite,sx_bot,sy_bot,sz_bot,sxy_bot,syz_bot,sxz_bot
(F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3)
*vwrite,sx_bot,sy_bot,sz_bot,sxy_bot,syz_bot,sxz_bot
(F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3)

*vwrite,sx_top,sy_top,sz_top,sxy_top,syz_top,sxz_top
(F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3)
*vwrite,sx_top,sy_top,sz_top,sxy_top,syz_top,sxz_top
(F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3)
*vwrite,sx_top,sy_top,sz_top,sxy_top,syz_top,sxz_top
(F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3,4X,F10.3)

*vwrite
('!')
*enddo


*cfc


C*********************************************************
C*** READ INITIAL STRESS FILE AND SOLVE
C*********************************************************
isfile,,,,,1
solv