Learning Forum

[me230003066]

Hello!
I want to find the damping coefficient of a viscoelastic material. For that I thought of doing the harmonic analysis and finding the amplitude response over varied frequency. Then using half power bandwidth method I can get the damping coefficient. I don't know if the approach is correct or not, rectify me if wrong. The main problem that I find here is assingning material properties. I assigned density, isotropic elesticity and then prony shear relaxation terms but that is not giving me satisfactory results. 
If someone know how to assign properties to viscoelastic material please let me know. 

[dlooman]

That's the correct approach.  Here's an APDL example:

/PREP7

 

! Allow hyperelasticity with harmonic analysis

ELMAT,MERROR,WARNING

 

! Geometry and mesh

pi = 2.0*acos(0)

Lx=1

y1=3.0

y2=y1+0.25

Lz=1

BLOCK,0,Lx,0,y1,0,Lz

BLOCK,0,Lx,y1,y2,0,Lz

ET,1,SOLID185

KEYOPT,1,6,0

ES = Lx/4.

ESIZE,ES

MAT,1

VMESH,1

MAT,2

VMESH,2

 

nsel,s,loc,y,y1

nummrg,node

 

!  Material # 1 -> approximates a massless spring and damper 

 

MP,DENS,1,0   ! no density for spring/dashpot material

E0=10.0    ! spring stiffness

Einf=1E5   ! stiffness for infinite strain rate

E1=Einf-E0 ! stiffness of spring attached to dashpot

 

MP,EX,1,Einf

MP,PRXY,1,0.0

 

! - - Convert linear elastic to Neo Hookean

matid=1

*get,dex,ex,matid

*get,dnu,nuxy,matid

mpdele,ex,matid

mpdele,nuxy,matid

neo_mu = dex/2/(1+dnu)

neo_d = 2/(dex/3/(1-2*dnu))

TB,HYPER,matid,,,NEO

TBDATA,1,  neo_mu,neo_d

! - - - - - - - - - - - - - - -

 

! critical damping coefficient

cc=0.816497E-01   ! y1=3.0

 

! actual damping coefficient

c=cc/5  

 

alpha = 1.0 - E0/E1

tau=c/(E1/y1)

 

TB,PRONY,1, ,1,SHEAR

TBDATA,1,  alpha, tau

 

TB,PRONY,1, ,1,BULK

TBDATA,1,  alpha, tau

 

! material #2 -> approximates a rigid mass

MP,DENS,2,0.002

MP,EX,2,1E6

MP,PRXY,2,0.0

 

! Boundary conditions for uniaxial motion

NSEL,S,LOC,Y,0.

D,All,Uy,0.

NSEL,ALL

D,All,Uz,0.

D,All,Ux,0.

 

/SOL

decades = 2  ! number of frequency decades

nf = 50       ! number of solutions per decade

f0 = 1E-0  ! starting frequency

df = (9.0*f0)/nf ! initial frequency increment 

jt = decades*nf+1  ! total number of cycles

 

ANTYPE,HARMIC

HROPT,FULL

HROUT,ON

KBC,0

NSUBST,NSUB

outres,all,all

 

! apply a force to top center node

nsel,s,loc,y,y2

nsel,r,loc,x,lx/2

nsel,r,loc,z,lz/2

f,all,fy,1e-3

 

freq=f0

*do,j,1,jt,1

 

 HARFRQ,0,freq

  allsel,all

  SOLVE  

 

  freq = freq+df

 

  ! increase frequency step if freq is in a new decade 

  tf0 = 10.0*f0

  *if,freq,ge,tf0,THEN

    f0 = 10.0*f0

    df = 10.0*df

  *endif

*enddo

FINISH

[me230003066]

Thank you for your Answer!
I just have one doubt, what are the essential material properties that we need to provide to the material so that it acts as a damping or viscoelastic material?

[me230003066]

Thank you so much for your Answer!
I just have one doubt, what are the essential material properties that we need to provide to the material so that it acts as a damping or viscoelastic material?

[dlooman]

Damping is mentioned in the example I provided.  Perhaps an AI search can provide background on that topic.