Learning Forum

[jesusepp]

Greetings,

I set up a simple harmonic simulation in MAPDL of a model of a block that is excited from one end with a harmonic displacement in the Z direction (1 meter amplitude), and I am recording the frequency response function of a node in its tip. If I am imposing a harmonic displacement in one end, logic tells that the displacement frequency response of the opposite end should have the same amplitude for a 0 Hz or very low frequency (below the first resonance of the structure). Nonetheless, I am not getting such a response, I am obtaining a zero-displacement response that increases linearly with frequency, which does not have a physical meaning for the presented problem. What could be the problem? I tried the same setup using the regular ANSYS Mechanical interface, and the results of displacement at low frequencies do match the imposed excitation, which indicates that there is a problem in the APDL script.

The code I used is the following:

!!!!!!!!!!!!!!!!!!!!!!!!

FINISH                  ! Finish any possible active processor

/CLEAR                  ! Clear all previous information running on the program

/TITLE,Test - Harmonic Analysis

! -------- Model Creation Processor initialization --------

/PREP7

ET,1,186                    ! SOLID186 Structural solid - Brick (20-Node, 3 Dof per node UX,UY,UZ)

MP,EX,1,205e9               ! Elastic modulus [Pa]

MP,NUXY,1,0.3               ! Minor Poisson ratio on XY

MP,DENS,1,7890              ! Mass density [kg/m^3]

BLOCK,0,34e-3,0,1e-3,0,0.73e-3       ! Main geometry

ALLSEL

! Meshing process

MSHAPE,0            ! Quadrilateral mesh (1 for tetrahedral elements)

MSHKEY,1            ! Free meshing

ALLSEL

MAT,1               ! Substructral material

TYPE,1              ! Structural Solids

VMESH,ALL           ! Mesh selected component

ALLSEL

NUMMRG,ALL,T_1*1e-5

ALLSEL                      ! Default to select all components

NPLOT,1                     ! Plot nodes in GUI

FINISH

/SOLU

ANTYPE,HARMIC       ! Analysis type -> Harmonic (Coupled field)

HROPT,AUTO          ! Type of solver - Full for displacement-based excitations

NSUBST,20           ! Number of frequency points to study

HARFRQ,0,10         ! Frequency range

DMPSTR,0.001        ! Structural damping coefficient

! Harmonic Displacement

NSEL,s,loc,x,0

D,ALL,UZ,1

D,ALL,UX,0

D,ALL,UY,0

ALLSEL

SOLVE

FINISH

! COMPUTE THE FRF OF A SINGLE NODE

/POST26

NUMVAR,10

NSEL,s,LOC,z,0.73e-3

*GET,xloc,NODE,0,MXLOC,X

*GET,yloc,NODE,0,MNLOC,Y

NSEL,r,LOC,x,xloc

NSEL,r,LOC,y,yloc

newNode = NDNEXT(0)

NSOL,2,newNode,U,Z

PLVAR,2         ! Displacement

PRVAR,2

FINISH

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

 

Additionally, this is a picture of my output FRF. Vertical axis is the displacement in [m] and horizontal axis is the frequency in [Hz]

 

For the same setup in Mechanical UI, I obtained the following results, correctly representing the expected behavior:

[Ashish Khemka]

Hello,

In Ansys Mechanical, go to Solution, right click, open solver files directory, and look for the ds.dat file. It is an input to the MAPDL solver, and you can compare the difference between input code you have used and the one that Mechanical is generating. 

Regards,

Ashish Khemka

[dlooman]

The (not very good) default in APDL is KBC,0 which ramps the unit displacement from zero vs frequency.  In Mechanical, KBC,1 is set by default.

[jesusepp]

I applied the adjustment (KBC,1), and now the results match! Thanks for the support