Learning Forum

[Arunjyoti Sarkar]

Hello All,

I am trying to do a harmonic analysis of a vertical cantilever standing in water using HROCEAN command.

The structure is simple. I have attached the full command list below.

It seems that the simulation is running, but I am not able to get any plot in POST. 

If anyone knows how to use this command properly, please go through and let me know what mistake I am making there.

Thanks in advance

Arun

------------------------------

!!!!!!!!!!!!!!!!!   Structure start
/PREP7  
!*  
/NOPR   
KEYW,PR_SET,1   
KEYW,PR_STRUC,1 
KEYW,PR_THERM,0 
KEYW,PR_FLUID,0 
KEYW,PR_ELMAG,0 
KEYW,MAGNOD,0   
KEYW,MAGEDG,0   
KEYW,MAGHFE,0   
KEYW,MAGELC,0   
KEYW,PR_MULTI,0 
/GO 
!*  
/COM,   
/COM,Preferences for GUI filtering have been set to display:
/COM,  Structural   
!*  
!*  
ET,1,BEAM188
!*  
!*  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e9  
MPDATA,PRXY,1,,.3   
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,7850 
*CSET,1,2,       1,2,   
MPCOPY, ,1,2
TBCOPY,ALL,1,2  
!*  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDE,DENS,2 
MPDATA,DENS,2,,1025 
SECTYPE,   1, BEAM, CTUBE, , 0  
SECOFFSET, CENT 
SECDATA,2.96,3,0,0,0,0,0,0,0,0,0,0 
!!!!!!!!!!!!!!!!!!!!!!!
N, ,,,-50,,,,   
N, ,,,-45,,,,   
N, ,,,-40,,,,   
N, ,,,-35,,,,   
N, ,,,-30,,,,   
N, ,,,-25,,,,   
N, ,,,-20,,,,   
N, ,,,-15,,,,   
N, ,,,-10,,,,   
N, ,,,-5,,,,
N, ,,,,,,,  
N, ,,,5,,,, 
N, ,,,10,,,,
N, ,,,15,,,,
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! 
TYPE,   1   
MAT,       1
REAL,   
ESYS,       0   
SECNUM,   1 
TSHAP,LINE  
!*  
FLST,2,2,1  
FITEM,2,1   
FITEM,2,2   
E,P51X  
FLST,2,2,1  
FITEM,2,2   
FITEM,2,3   
E,P51X  
FLST,2,2,1  
FITEM,2,3   
FITEM,2,4   
E,P51X  
FLST,2,2,1  
FITEM,2,4   
FITEM,2,5   
E,P51X  
FLST,2,2,1  
FITEM,2,5   
FITEM,2,6   
E,P51X  
FLST,2,2,1  
FITEM,2,6   
FITEM,2,7   
E,P51X  
FLST,2,2,1  
FITEM,2,7   
FITEM,2,8   
E,P51X  
FLST,2,2,1  
FITEM,2,8   
FITEM,2,9   
E,P51X  
FLST,2,2,1  
FITEM,2,9   
FITEM,2,10  
E,P51X  
FLST,2,2,1  
FITEM,2,10  
FITEM,2,11  
E,P51X  
FLST,2,2,1  
FITEM,2,11  
FITEM,2,12  
E,P51X  
FLST,2,2,1  
FITEM,2,12  
FITEM,2,13  
E,P51X  
FLST,2,2,1  
FITEM,2,13  
FITEM,2,14  
E,P51X  
FLST,2,1,1,ORDE,1   
FITEM,2,1   
!*  
/GO 
D,P51X,ALL,0, , , , , , , , ,   
ACEL,0,0,9.807, 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! 
SAVE
!!!!!!!!!!!!!!!!!!!   Structure end
FDELETE,ALL
OCDELETE,ALL
OCTYPE,BASIC
OCDATA,50,2,1,,,1,0,1  
OCTABLE,,,0.7,0.7,0,2,2 
OCTYPE,WAVE 
OCDATA,0,180,1,0,0,0  
OCTABLE,5,10
OCTABLE,5,12
OCTABLE,5,14
OCTABLE,5,16
OCTABLE,5,18
SAVE 
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!HROCEAN,HARMONIC,20
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FINISH
/SOL
!HROCEAN,HARMONIC,20
!*
ANTYPE,3
HROCEAN,HARMONIC,20
TIME,5
!*  
!*  
HROPT,FULL
HROUT,ON
OUTPR,ESOL,ALL
LUMPM,0 
!*  
EQSLV, ,1e-06,  
PSTRES,0
!*  
/STATUS,SOLU
SOLVE   
FINISH  
!!!!!!!!!!!!!!!!!!!!!!!!!!
/POST1  
SET,LIST
FINISH  
/POST26 
FILE,'TEST1','rst','.'  
/UI,COLL,1  
NUMVAR,200  
SOLU,191,NCMIT  
STORE,MERGE 
PLCPLX,0
PRCPLX,1
FILLDATA,191,,,,1,1 
REALVAR,191,191 
FORCE,TOTAL 
!*  
!*  
ESOL,2,1,1 ,F,X,FX_2
STORE,MERGE 
XVAR,1  
PLVAR,2,

[dlooman]

Your results seem to be all zero.  Here's a qa test.  Maybe you can modify it to do what you want.

/title,ocha-4s,vkumar,verify hrocean harmonic loading,PIPE288
/COM,***************************************************************************
/COM, TEST OBJECTIVE: Perform harmonic analysis on PIPE288 using HROCEAN command
/COM,
/COM,
/COM, ELEMENTS: PIPE288(KEYOPT(12)=3)
/COM, 
/COM, MATERIAL: ELASTIC
/COM,
/COM, DESCRIPTION: 
/COM, A vertical tube consisting of only one element fully submerged 
/COM, in water is constrained in all degrees of freedom at bottom node.            
/COM, The wave loading is applied to the model and harmonic analysis is              
/COM, performed using the ocean wave table to extract the reactions and             
/COM, tip displacements.The data base of case1 is saved and reused in case2. 
/COM,
/COM,
/COM, Case1: The wave is applied and harmonic analysis is done with 
/COM,        HROCEAN,HARMONIC command using ocean wave table
/COM,        
/COM,
/COM, Case2: The real and imaginary forces of the wave obtained from 
/COM,        Case1 is applied at nodes to same model using keyopt(12)=2
/COM,        and by setting a tiny wave height in ocean wave table. Ocean
/COM         environment is deleted using HROCEAN,OFF and by not issuing  
/COM,        ocean id to pipe section. The harmonic analysis is performed 
/COM         at wave excitation frequency using HARFRQ.
/COM,
/COM, Expected Results: 1. The reactions and tip displacements obtained 
/COM,                      in complex form  from Case1 and Case2 should match. 
/COM, 
/COM,********************************************************             
/COM, CASE 1:Harmonic analysis using HROCEAN,HARMONIC
/COM,******************************************************** 
/out,scratch
/COM, Input Parameters
noe    =1                             ! number of elements
pi     =3.14159265                    ! circumference/diameter of a circle
L      =100                           ! length of pipe
ER     =2.10e+11                      ! Young's modulus of pipe
PRATIO =0.0                           ! Poisson's ratio
Do     =0.533                         ! outer diameter of pipe
Di     =0.508                         ! inner diameter of pipe
Thk    =(Do-Di)/2                     ! thickness of pipe  
RHOP   =0.00000030                    ! density of pipe
RhoW   =1025.0                        ! density of water 
Cd     =1.0                           ! drag coefficient
Cm     =1.0                           ! inertia coefficient   
Depth  =100.0                         ! depth of ocean
H      =4.0                           ! height of wave
T      =10.0                          ! time period of wave
sfvel  =0.2                           ! velocity of current at top surface  
depvel =0.3                           ! velocity of current at ocean floor  
NPHASE =8
                    
/PREP7                                
/COM, Material properties
MP,EX  ,1,ER
MP,PRXY,1,PRATIO
MP,DENS,1,RhoP
MP,DENS,2,RhoW

/COM, Element and keyopts
ET,1,PIPE288
KEYOPT,1,12,3
KEYOPT,1,15,0
KEYOPT,1,6,1

/COM, Section properties
SECTYPE,1,PIPE
SECDATA,Do,Thk

/COM, Finite element modeling
N,1,,,-90
N,2,,,-L
E,1,2
SAVE,,DB

/COM, Ocean Basic data
OCTYPE,BASIC
OCDATA,Depth,2,,0,,0
OCTABLE,,,Cd,,0,Cm

/COM, Ocean Wave data
OCTYPE,WAVE
OCDATA,0                  ! Small Amplitude Airy Wave theory
OCTABLE,H,T,0
FINISH

/SOLU
ANTYPE,HARM
ACEL,,,9.8
D,2,ALL
TIME,1e-011
HROCEAN,HARMONIC,NPHASE
OUTRES,ALL,ALL
OUTPR,ALL,ALL
SOLVE
FINISH

/POST26
ESOL,2,1,1,f,x,FX_1
ESOL,3,1,1,f,z,FZ_1
ESOL,4,1,2,f,x,FX_2
ESOL,5,1,2,f,z,FZ_2
NSOL,6,1,U,X,UX_TIP
PRVAL,2,3,4,5,6
EXTREME,2,5,6
FINISH

/POST1
SET,1,,,real
PRNLD,F
SET,1,,,imag
PRNLD,F
SET,1,,,real
PRRSOL,F
*GET,FX1_REAL,NODE,2,RF,FX,REAL
*GET,UX1_REAL,NODE,1,U,X,,REAL
SET,1,,,imag
PRRSOL,F
*GET,FX1_IMAG,NODE,2,RF,FX,IMAG
*GET,UX1_IMAG,NODE,1,U,X,,IMAG
FINISH
PARSAVE
PARRES
/out,
/COM************************************************************
/COM Expected results: The reaction forces and tip displacements 
/COM                   for case 1 and 2 should match
/COM************************************************************ 
/COM Real reaction for case 1
  *STATUS,FX1_REAL
/COM,***********************************************************
/COM Imaginary reaction for case 1
  *STATUS,FX1_IMAG
/COM,***********************************************************
/COM Real component of displacement for case 1
*STATUS,UX1_REAL
/COM,***********************************************************
/COM Imaginary component of displacement for case 1
*STATUS,UX1_IMAG
/COM,***********************************************************

/CLEAR,NOSTART
/COM,**************************************************************             
/COM, CASE 2:HROCEAN,OFF and HARFRQ
/COM,************************************************************** 
PARRES
/out,scratch

/PREP7
RESUME,,DB
/COM, Ocean Basic data
OCTYPE,BASIC
OCDATA,Depth,2,,0,,0
OCTABLE,,,Cd,0,0,Cm

/COM, Ocean Wave data
OCTYPE,WAVE
OCDATA,0                  ! Small Amplitude Airy Wave theory
OCTABLE,1e-011,1e+11,0

/SOLU
ANTYPE,HARMIC
HROCEAN,OFF
OCDELETE,all !2,3,1
HARFRQ,0,1/T
ACEL,,,9.8
NSUBST,10
TIME,1e-11
F,1,FX,1.9901,-33.470
F,2,FX,1.8871,-32.592 
D,2,ALL
OUTRES,ALL,ALL
SOLVE
FINISH

/POST26
NUMVAR,100
ESOL,12,1,1,F,X
ESOL,13,1,1,F,Z
ESOL,14,1,2,F,X
ESOL,15,1,2,F,Z
NSOL,16,1,U,X,UX_TIP
PRVAR,12,13,14,15,16
FINISH

/POST1
FLIST
SET,1,,,real
PRNLD,F
SET,1,,,imag
PRNLD,F
SET,1,,,real
PRRSOL,F
*GET,FX2_REAL,NODE,2,RF,FX,REAL
*GET,UX2_REAL,NODE,1,U,X,,REAL
SET,1,,,imag
*GET,FX2_IMAG,NODE,2,RF,FX,IMAG
*GET,UX2_IMAG,NODE,1,U,X,,IMAG
PRRSOL,F
FINISH
PARSAVE
PARRES
/out,
/COM,***********************************************************
/COM Real reaction for case 2
  *STATUS,FX2_REAL
/COM,***********************************************************
/COM Imaginary reaction for case 2
  *STATUS,FX2_IMAG
/COM,***********************************************************
/COM Real component of displacement for case 2
*STATUS,UX2_REAL
/COM,***********************************************************
/COM Imaginary component of displacement for case 2
*STATUS,UX2_IMAG
/COM,***********************************************************
/EXIT,NOSAVE