Learning Forum

[Micheleb]

Hi everyone,

I'm working on a project which involves a body suspended on a series of springs (COMBIN14 with k and c given through Real constants) and I need to perform a Spectrum Analysis. They gave me the PSD levels [G^2/Hz] and I successfully performed the base eccitation. In order to use Miles' eq. I extracted the RPSD value of RELATIVE acceleration @CoG in /post26: is this the transmissibility I need?

I also took a look at the "RPSD values of fixed nodes in terms of ABSOLUTE acceleration" MINUS "RPSD values @CoG in terms of ABSOLUTE acceleration" but I don't find a correlation with relative acceleration; what does this mean?

Thank you for helping!

Michele :)

[Bill Bulat]

Hello Michele This may not answer all of your questions, but for what it's worth, the following MAPDL input posits a spring-mass system with a damping ratio (DMPRAT command) subjected to a flat unit acceleration PSD. The one sigma UY displacement of node #2 is determined three ways:
1) In POST1 from the SET,3,1 results set
2) In POST26 by taking the square root of the integral of the RPSD of the UY response of node 2 over frequency (a trick I learned in college)
3) Miles' equation (a trick I learned from you)
Results from all three agree well. Notice that I defined the input PSD values in units of acceleration rather than G^2/Hz because of the note in the source I found while researching Miles' equation:
https://femci.gsfc.nasa.gov/random/MilesEqn.html
"NOTE: in this form of the equation, since we want units of length, the ASDinput must be in units of [length/sec2]2/[Hz].You will most likely have to convert your ASD data from g2/Hz to something else."

Best Bill



fini
/cle
/sys,del file*.png


C**********************************************
C*** PARAMETERS
C**********************************************
pi=acos(-1)
k=1000 ! STIFFNESS (N/m)
m=1 ! MASS (kg)
zeta=0.05 ! DAMPING RATIO

wn=sqrt(k/m) ! UNDAMPED NATURAL FREQUENCY, DO NOT EDIT
fn=(1/(2*pi))*wn
Q=1/(2*zeta) ! Q FACTOR, DO NOT EDIT

/title,m = %m% kg, k = %k% N/m, zeta = %zeta%


C**********************************************
C*** MODEL
C**********************************************
/prep7
n,1
n,2,,1

et,1,14,,2
r,1,k !,c
et,2,21,,,4
r,2,m

type,1 $real,1 $e,1,2
type,2 $real,2 $e,2
d,1,ux
d,1,uy
d,2,ux

fini


C**********************************************
C*** MODAL ANALYSIS
C**********************************************
/solu
anty,modal
modo,lanb,1
mxpa,all,,,yes
alls
save
solve
fini


C**********************************************
C*** PSD ANALYSIS
C**********************************************
/solu
anty,spec
spopt,psd,1,yes
psdu,1,acel

psdfreq,1,,0.75*fn,1.25*fn ! FLAT SPECTRUM IN Y DIRECTION
psdv,1,1,1
sed,,1

d,1,uy,1 ! BASE EXCITATION

pfact,1,base
psdres,disp,abs
psdres,velo,abs
psdres,acel,abs

dmprat,zeta

solve
fini

/solu
anty,spec
psdcom,,,,total ! USE PSD COMBINATION METHOD
solv
fini


C**********************************************
C*** POST PROCESSING
C**********************************************
/post1
set,3,1 ! READ 1 SIGMA DISPLACEMENT RESULTS INTO DATABASE
uy1=uy(2) ! ONE SIGMA UY DISPLACEMENT OF NODE 2
pldi
fini

/post26 ! ALTERNATE "MANUAL" CALCULATION OF ONE SIGMA UY DISPLACEMENT OF NODE 2
store,psd
nsol,2,2,u,y
rpsd,3,2,,1,1,UY2
int1,4,3,1,,INT_UY2
*get,uy2,vari,4,extrem,vmax
uy2=sqrt(uy2)


C************************************************************
C*** MILES EQUATION
C*** https://femci.gsfc.nasa.gov/random/MilesEqn.html
C***
C*** "NOTE: in this form of the equation, since we want units of length C*** the ASDinput must be in units of [length/sec2]2/[Hz].
C*** You will most likely have to convert your ASD data from g2/Hz to something else."
C*************************************************************
uy_miles=sqrt((q*1)/(32*pi**3*fn**3))


/ann,dele
/tla,-0.50,0.90,UY1 = %UY1% (POST1 NODAL RESULTS FROM SET,3,1)
/tla,-0.50,0.85,UY2 = %UY2% (SQRT OF INTEGRAL OF RPSD IN POST26)
/tla,-0.50,0.80,UY_MILES = %UY_MILES% (RMS VALUE FROM MILES' EQUATION)
/axl,y,UY of NODE #2
plva,3
/sho,png $plva,3 $/sho,close

/eof

[Micheleb]

Thank you we have been very helpful! I really appreciated the script part along with the comments. I have done some testing and I think I can say that this methods converge only if there's just one natural mode and if the input is a step input, otherwise Miles' one gives strange results.
Linked to this, how do you think I could calculate GRMS of the second or third peak of acceleration? The problem with method n.1 is that SET,3,1 gives me the maximum, whereas methods n.2 involves the integral of RPSD of U, so it changes if I change the bandwidth (extremes of integration).

Thank you again for your time
Michele :)