/PREP7

ET,1,PLANE182
ET,2,PLANE182
ET,3,TARGE169
ET,4,CONTA172

KEYOPT,1,1,2
KEYOPT,1,3,2
KEYOPT,2,1,2
KEYOPT,2,3,2

KEYOPT,4,10,1
KEYOPT,4,12,5
KEYOPT,4,5,3
KEYOPT,4,9,1


/COM, CZM PARAMETERS
TAU_N=21.63
G1=0.43
ETA=0.00005
ALPHA=2
K_n=-1.8E3
K_s=-0.56E3

MP,EX,1,204E3               !AA6082
MP,PRXY,1,0.25

TB,CZM,2,,,CBDE
TBDATA,1,TAU_N,G1,,,ETA,0,ALPHA

/COM, ADHEREND
RECTNG,0,300,0,12.7
RECTNG,0,300,0,-12.7

LSEL,S,LINE,,1,7,6
LESIZE,ALL,0.1

LSEL,S,LINE,,3,5,2
LESIZE,ALL,2

ALLSEL,ALL


TYPE,1
MAT,1
AMESH,1
CSYS,0

TYPE,2
MAT,1
AMESH,2
CSYS,0

TYPE,3
MAT,2
REAL,3
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,X,55,300
NSEL,R,LOC,Y,0
ESURF

TYPE,4
MAT,2
REAL,3
RMODIF,3,3,K_n
RMODIF,3,12,K_s
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,Y,0
NSEL,R,LOC,X,55,300
ESURF

FINISH

/SOLU

ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,X,0
NSEL,R,LOC,Y,12.7
D,ALL,UY,5

NSEL,ALL
ESEL,ALL

ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,X,0
NSEL,R,LOC,Y,-12.7
D,ALL,ALL

NSEL,ALL
ESEL,ALL


SELTOL,0.1
NSEL,S,LOC,X,300
D,ALL,ALL

SELTOL

NSEL,ALL
ESEL,ALL


NLGEOM,ON

TIME,1

AUTOTS,ON
NSUBST,1500,2000,1500,OFF

NEQIT,100,20

OUTRES,ALL,ALL

SOLVE

FINISH


/POST26
NSEL,S,LOC,Y,12.7
NSEL,R,LOC,X,0
*GET,TOPLOAD,NODE,0,NUM,MAX
NSEL,ALL

NSOL,2,TOPLOAD,U,Y,UY
RFORCE,3,TOPLOAD,F,Y,FY
PROD,4,3,,,RF,,,25

/AXLAB,X,DISP U (mm)
/AXLAB,Y,REACTION FORCE R (N)
/YRANGE,0,2000
XVAR,2
PLVAR,4
PRVAR,UY,FY,RF